Temperatur-Sensor TMP36

Die TMP35/TMP36/TMP37 sind Niedervolt-, Präzisions-Celsius-Temperatursensoren. Sie liefern einen Spannungsausgang, der linear proportional zur Celsius-Temperatur ist. Der TMP35/TMP36/TMP37 erfordert keine externe Kalibrierung, um typische Genauigkeiten von ±1°C bei +25°C und ±2°C über den Temperaturbereich von -40°C bis +125°C zu liefern.

Eigenschaften

• Niederspannungsbetrieb (+2,7V bis + 5,5V)
• Direkt in °C kalibriert
• 10mV / 8°C Skalenfaktor (20mV / 8°C auf TMP37)
• ±2°C Genauigkeit Übertemperatur (Typ)
• ±0,5°C Linearität (Typ)
• Stabil mit großen kapazitiven Lasten
• Spezifiziert -40°C bis +125°C, Betrieb bis +150°C
• Weniger als 50μA Ruhestrom
• Abschaltstrom 0,5μA max

Pinout

Verwendete Bauteile

• Grundlegende Werkzeuge und Hilfsmittel
• Arduino UNO (oder kompatibles Board)
• TMP36-Sensor
• Steckkabel ("Jumperkabel")
• Steckbrett ("Breadboard")

Aufbau

Sketch

#define TMP36_PIN A0
#define AREF_VOLTAGE 5.0   // depends if we´re using 3.3V or 5.0V for operating the TMP36

void setup()
{
    Serial.begin(9600);
}

void loop()
{
    unsigned int sensorValue;
    float voltage, degreesCelsius;

    sensorValue = analogRead(TMP36_PIN);
    voltage = getVoltage(sensorValue);
    degreesCelsius = getTemperature(voltage);

    Serial.print("SensorValue: ");
    Serial.print(sensorValue);
    Serial.print("; Voltage: ");
    Serial.print(voltage);
    Serial.print("V; Temperature: ");
    Serial.print(degreesCelsius);
    Serial.println("°C");

    delay(1000);
}

/**
 * Converts the 0 to 1023 value from analogRead() into a 0.0 to 5.0
 * value that is the true voltage being read at that pin.
 */
float getVoltage(int sensorValue)
{
    return (sensorValue * AREF_VOLTAGE / 1024);
}

/**
 * Converting the voltage to degrees Celsius.
 * The formula comes from the datasheet of the TMP36
 */
float getTemperature(float voltage)
{
    return (voltage - 0.5) * 100.0;
}