DFPlayer-Modul

Merkmale des DFPlayer

• Unterstützt MP3- und WAV-Decodierung
• Unterstützt das Dateisystem FAT16 und FAT32
• 24-Bit-DAC-Ausgabe und unterstützt den dynamischen Bereich 90dB und SNR 85dB
• Unterstützt den AD-Key-Steuerungsmodus und den seriellen UART-RS232-Steuerungsmodus
• Unterstützt maximal 32GB Micro SD-Karte
• Unterstützt maximal 3000 Audiodateien im Stammverzeichnis des Speichermediums
• Unterstützt maximal 9999 Audiodateien im Ordner \MP3
• Unterstützt maximal 9999 Audiodateien im Ordner \ADVERT (unterbrechende Werbeeinblendungen)
• Unterstützt maximal 100 Ordner und jeder Ordner kann 1000 Audiodateien speichern
• Unterstützt die zufällige Wiedergabe der Dateien
• Eingebauter 3-Watt-Verstärker, der einen 3-Watt-Lautsprecher direkt ansteuern kann
• Einstellbar Lautstärke (30 Stufen)
• Einstellbarer Equalizer (10 Stufen)

Technische Daten

• MP3-Audioformat: Unterstützt 11172-3 und ISO13813-3 Layer3 Audio-Decoding
• Unterstützt verschiedene Sampling-Raten (8/11.025/12/16/22.05/24/32/44.1/48 kHz)
• Unterstützt verschiedene Equalizer-Modi (Normal, Pop, Rock, Jazz, Classic, Bass)
• USB-Port: Standard USB 2.0
• UART-Port: Standardisierte serielle Schnittstelle mit TTL-Pegel (Parameter: 9600, 8, N, 1)
• Betriebsspannung: 3,3V bis 5,0V; typisch 4,2V
• Standby-Strom: 20mA

Anschlüsse

Bedienung

Zum Steuern des MP3-Moduls steht eine serielle Schnittstelle zur Verfügung. Eine Befehlssequenz besteht immer aus zehn Byte:

Die Prüfsumme berechnet sich aus der folgenden Formel:
0 - Versionsbyte - Anzahl der Bytes - Commandbyte - Feedback - Parameter_MSB - Parameter_LSB
Wenn dann das Ergebnis im Hexadezimalformat vorliegt, ergeben die rechten vier Stellen der Hexadezimalzahl die Prüfsumme. Aus diesen nunmehr vier Stellen ergeben die linken zwei Stellen (ein Byte) das Checksum_MSB und die rechten zwei Stellen (ein Byte) das Checksum_LSB.

Dateinamen

Audiodateien, die direkt im Hauptverzeichnis des Speichermediums (SD-Karte oder USB-Flash) gespeichert sind (maximal 3000 Dateien), müssen in 0001.mp3 / 0001.wav, 0002.mp3 / 0002.wav, 0003.mp3 / 0003.wav, ....... 3000.mp3 / 3000.wav usw. umbenannt werden.
Nach dem vierstelligen numerischen Wert kann weiterer Text entsprechend dem verwendeten FAT-Format verwendet werden (z.B. 0001_Testdatei.MP3)
Grundsätzlich unterstützt das Modul auch verschiedene Unterverzeichnisse \00 bis \99 mit dreistelligen Dateinamen (001.MP3 bis 255.MP3).
In den Ordnern "/MP3" und/oder "/ADVERT" können jeweils bis zu 9999 Dateien gespeichert werden. Die oben genannten Namensregeln gelten aber auch hier.

Hinweis: Es ist wichtig zu wissen, dass in der Folge beim Absetzen eines Befehls keine tatsächlichen Dateinamen übergeben werden, sondern eine Platznummer welche sich aber auf die tatsächliche physikalische Position in der Dateizuordnungstabelle (FAT) des Mediums bezieht und nichts mit dem Dateinamen zu tun hat. Von daher ist es von essentieller Bedeutung in welcher Reihenfolge die Dateien auf das Speichermedium übertragen werden.

Aufbau mit "AD-Key-Modul"

Minimaler Aufbau

Aufbau mit dem Arduino

Steuerbefehle

Hinweis: Es kann sein, dass nicht jeder Befehl bei jedem Modul funktioniert oder plausible Daten zurück gibt.

Befehle

Abfragen

Verwendete Bauteile

• Grundlegende Werkzeuge und Hilfsmittel
• Arduino UNO (oder kompatibles Board)
• DFPlayer Mini Mp3-Player
• Micro SD-Karte (<= 32GB)
• Lautsprecher (<= 3Watt)
• Steckkabel ("Jumperkabel")
• Steckbrett ("Breadboard")

Der folgende Sketch ist eine Demo, die auf der Library DFRobotDFPlayerMini basiert:

#include "Arduino.h"
#include "SoftwareSerial.h"
#include "DFRobotDFPlayerMini.h"

SoftwareSerial mySoftwareSerial(10, 11); // RX, TX
DFRobotDFPlayerMini myDFPlayer;
void printDetail(uint8_t type, int value);

void setup()
{
    mySoftwareSerial.begin(9600);
    Serial.begin(9600);
    Serial.println();
    Serial.print(F("Init DFPlayer..."));
    if (!myDFPlayer.begin(mySoftwareSerial)) {
        Serial.println(F("Error!"));
        while(true);
    }
    Serial.println(F("[ok]"));

    //Set volume value. From 0 to 30
    myDFPlayer.volume(17);

    myDFPlayer.play(1); // Play the first mp3
}

void loop()
{
    static unsigned long timer = millis();

    //Play next mp3 every 10 seconds
    if (millis() - timer > 10000) {
        timer = millis();
        myDFPlayer.next();
    }

    if (myDFPlayer.available()) {
        printDetail(myDFPlayer.readType(), myDFPlayer.read()); //Print the detail message from DFPlayer to handle different
    }
}

void printDetail(uint8_t type, int value)
{
    switch (type) {
        case TimeOut:
            Serial.println(F("Time Out!"));
            break;
        case WrongStack:
            Serial.println(F("Stack Wrong!"));
            break;
        case DFPlayerCardInserted:
            Serial.println(F("Card Inserted!"));
            break;
        case DFPlayerCardRemoved:
            Serial.println(F("Card Removed!"));
            break;
        case DFPlayerCardOnline:
            Serial.println(F("Card Online!"));
            break;
        case DFPlayerPlayFinished:
            Serial.print(F("Number:"));
            Serial.print(value);
            Serial.println(F(" Play Finished!"));
            break;
        case DFPlayerError:
            Serial.print(F("DFPlayerError:"));
            switch (value) {
                case Busy:
                    Serial.println(F("Card not found"));
                    break;
                case Sleeping:
                    Serial.println(F("Sleeping"));
                    break;
                case SerialWrongStack:
                    Serial.println(F("Get Wrong Stack"));
                    break;
                case CheckSumNotMatch:
                    Serial.println(F("Check Sum Not Match"));
                    break;
                case FileIndexOut:
                    Serial.println(F("File Index Out of Bound"));
                    break;
                case FileMismatch:
                    Serial.println(F("Cannot Find File"));
                    break;
                case Advertise:
                    Serial.println(F("In Advertise"));
                    break;
            }
            break;
    }
}